MOM_obsolete_diagnostics.F90

!> Provides a mechanism for recording diagnostic variables that are no longer
!! valid, along with their replacement name if appropriate.
module mom_obsolete_diagnostics
 
! This file is part of MOM6. See LICENSE.md for the license.
 
use mom_error_handler, only : mom_error, fatal, warning, is_root_pe
use mom_file_parser,   only : param_file_type, log_version, get_param
use mom_diag_mediator, only : diag_ctrl
use diag_manager_mod, only  : register_static_field_fms=>register_static_field
 
implicit none ; private
 
#include <MOM_memory.h>
 
public register_obsolete_diagnostics
 
contains
 
!> Scan through the diag_table searching for obsolete parameters and issue informational
!! messages and optionallly a FATAL error.
subroutine register_obsolete_diagnostics(param_file, diag)
  type(param_file_type),       intent(in)    :: param_file !< The parameter file handle.
  type(diag_ctrl),             intent(in)    :: diag       !< A structure used to control diagnostics.
! This include declares and sets the variable "version".
#include "version_variable.h"
  ! Local variables
  character(len=40)  :: mdl = "MOM_obsolete_diagnostics"  !< This module's name.
  logical :: foundentry, causefatal
  integer :: errtype
 
  call log_version(param_file, mdl, version)
  call get_param(param_file, mdl, "OBSOLETE_DIAGNOSTIC_IS_FATAL", causefatal,              &
                 "If an obsolete diagnostic variable appears in the diag_table, "//        &
                 "cause a FATAL error rather than issue a WARNING.", default=.true.)
 
  foundentry = .false.
  ! Each obsolete entry, with replacement name is available.
  if (found_in_diagtable(diag, 'Net_Heat', 'net_heat_surface or net_heat_coupler')) foundentry = .true.
  if (found_in_diagtable(diag, 'PmE', 'PRCmE'))                                     foundentry = .true.
  if (found_in_diagtable(diag, 'froz_precip', 'fprec'))                             foundentry = .true.
  if (found_in_diagtable(diag, 'liq_precip', 'lprec'))                              foundentry = .true.
  if (found_in_diagtable(diag, 'virt_precip', 'vprec'))                             foundentry = .true.
  if (found_in_diagtable(diag, 'froz_runoff', 'frunoff'))                           foundentry = .true.
  if (found_in_diagtable(diag, 'liq_runoff', 'lrunoff'))                            foundentry = .true.
  if (found_in_diagtable(diag, 'calving_heat_content', 'heat_content_frunoff'))     foundentry = .true.
  if (found_in_diagtable(diag, 'precip_heat_content', 'heat_content_lprec'))        foundentry = .true.
  if (found_in_diagtable(diag, 'evap_heat_content', 'heat_content_massout'))        foundentry = .true.
  if (found_in_diagtable(diag, 'runoff_heat_content', 'heat_content_lrunoff'))      foundentry = .true.
  if (found_in_diagtable(diag, 'latent_fprec'))                                     foundentry = .true.
  if (found_in_diagtable(diag, 'latent_calve'))                                     foundentry = .true.
  if (found_in_diagtable(diag, 'heat_rest', 'heat_restore'))                        foundentry = .true.
  if (found_in_diagtable(diag, 'KPP_dTdt', 'KPP_NLT_dTdt'))                         foundentry = .true.
  if (found_in_diagtable(diag, 'KPP_dSdt', 'KPP_NLT_dSdt'))                         foundentry = .true.
 
  if (causefatal) then; errtype = fatal
  else ; errtype = warning ; endif
  if (foundentry .and. is_root_pe()) &
    call mom_error(errtype, 'MOM_obsolete_diagnostics: '//&
                            'Obsolete diagnostics found in diag_table')
 
end subroutine register_obsolete_diagnostics
 
!> Fakes a register of a diagnostic to find out if an obsolete
!! parameter appears in the diag_table.
logical function found_in_diagtable(diag, varName, newVarName)
  type(diag_ctrl),            intent(in) :: diag       !< A structure used to control diagnostics.
  character(len=*),           intent(in) :: varname    !< The obsolete diagnostic name
  character(len=*), optional, intent(in) :: newvarname !< The valid name of this diagnostic
  ! Local
  integer :: handle ! Integer handle returned from diag_manager
 
  ! We use register_static_field_fms() instead of register_static_field() so
  ! that the diagnostic does not appear in the available diagnostics list.
  handle = register_static_field_fms('ocean_model', varname, &
            diag%axesT1%handles, 'Obsolete parameter', 'N/A')
 
  found_in_diagtable = (handle>0)
 
  if (handle>0 .and. is_root_pe()) then
    if (present(newvarname)) then
      call mom_error(warning, 'MOM_obsolete_params: '//                        &
          'diag_table entry "'//trim(varname)//'" found. Use '// &
          '"'//trim(newvarname)//'" instead.' )
    else
      call mom_error(warning, 'MOM_obsolete_params: '//                        &
          'diag_table entry "'//trim(varname)//'" is obsolete.' )
    endif
  endif
 
end function found_in_diagtable
 
end module mom_obsolete_diagnostics